5.1.5. Sicherung von Benutzereinstellungen
|
Einige MOS'aik-Einstellungen können nicht automatisch wieder hergestellt werden. Falls hier wichtige Anpassungen vorgenommen wurden, sollten diese manuell gesichert werden. Legen Sie beispielsweise im
MOS'aik Dateiablageordner
einen Unterordner |
|
Folgende benutzerspezifische Einstellungen sind ggf. relevant:
-
Anpassungen des Spaltenlayouts der Tabellendarstellungen in den Arbeitsblättern.
Die Benutzereinstellungen der Spaltenlayouts werden lediglich in der Microsoft Windows Registry® abgelegt und gehen durch Anpassungen derselben Tabelle durch den Benutzer, durch ein Zurücksetzen der Tabelle über die Funktion Ansicht restaurieren oder auch durch die Deinstallation, das Update oder eine Neuinstallation von MOS'aik ggf. verloren.
Verwenden Sie für die Sicherung vor einem Update nicht die Menüfunktion Einstellungen speichern ....
Sollte das Spaltenlayout einer Tabellendarstellung relevant sein, wird empfohlen, die Einstellungen der Tabelle regelmäßig zu sichern.
Rufen Sie dazu beispielsweise die Menüfunktion auf und exportieren Sie regelmäßig Alle Datensätze in die Dateiablageordnerdatei
Einstellungen\Tabelle-<Benutzername>-<Tabellenname>-<Datum>.xls. Alternativ erstellen Sie eine Bildschirmaufnahme (Screenshot) oder ein Word®-Dokument, indem Sie die eingeblendeten Spaltennamen in der geforderten Reihenfolge aufschreiben.[84] -
Eigene Filter und Farbfilter der Tabellendarstellungen in den Arbeitsblättern.
Die Benutzereinstellungen der Filter werden lediglich in der Microsoft Windows Registry® abgelegt und gehen durch Anpassungen derselben Tabelle durch den Benutzer, durch Löschen des Filters oder auch durch die Deinstallation, das Update oder eine Neuinstallation von MOS'aik ggf. verloren.
Sollten die definierten Filter relevant sein, wird empfohlen, die Einstellungen der Filter mit einem Screenshot oder einer Dokumentation der Einstellungen zu sichern.
Öffnen Sie dazu beispielsweise das Kontextmenü und dokumentieren Sie die Einstellungen Ihrer persönlichen Filter in einer Dateiablageordnerdatei
Einstellungen\Filter-<Benutzername>-<Tabellenname>-<Datum>.xls. Alternativ erstellen Sie eine Bildschirmaufnahme (Screenshot) oder ein Word®-Dokument, indem Sie die Filterkriterien aufschreiben.
Das hier gezeigte Skript kann zur Sicherung der Benutzereinstellungen (Spaltenlayouts und Filter) des aktuell angemeldeten Benutzers sowie der gesamten MOS'aik Registry verwendet werden:
@ECHO OFF
:: INIT
SETLOCAL EnableDelayedExpansion
CHCP 65001 > nul
SET SKRIPT=%~0
SET TMPFILE1=%TEMP%\%~n0-%random%-1.tmp
SET TMPFILE2=%TEMP%\%~n0-%random%-2.tmp
:: BACKUP AUSGABEDATEI
SET ARCHIV=C:\MOSaik\Archivordner\Einstellungen
SET BACKUP_REG_SYSTEM=%ARCHIV%\moser-registry-system-%DATE%.reg
SET BACKUP_REG_USER=%ARCHIV%\%USERNAME%\moser-registry-%USERNAME%-%DATE%.reg
SET BACKUP_REG_USER_TXT=%ARCHIV%\%USERNAME%\moser-registry-%USERNAME%-%DATE%.txt
IF NOT EXIST "%ARCHIV%\%USERNAME%" MKDIR "%ARCHIV%\%USERNAME%"
:: MOSER SCHLÜSSEL
SET MOSER_KEY_SYSTEM=HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Moser
SET MOSER_KEY_USER=HKEY_CURRENT_USER\SOFTWARE\Moser
SET MOSER_KEY_PADS=%MOSER_KEY_USER%\Mosaik\Clients\*\Pads
:: SICHERUNG WICHTIGER REGISTRY EINSTELLUNGEN
@ECHO Backup Moser Registry Einstellungen >%TMPFILE1%
@ECHO ------------------------------------ >>%TMPFILE1%
@ECHO Datum: %DATE% >>%TMPFILE1%
@ECHO Computer: %COMPUTERNAME% >>%TMPFILE1%
@ECHO Benutzer: %USERNAME% >>%TMPFILE1%
@ECHO Skript: %SKRIPT% >>%TMPFILE1%
@ECHO Ausgabedatei (System): %BACKUP_REG_SYSTEM% >>%TMPFILE1%
@ECHO Ausgabedatei (User): %BACKUP_REG_USER% >>%TMPFILE1%
@ECHO Ausgabedatei (User): %BACKUP_REG_USER_TXT% >>%TMPFILE1%
:: Moser System Registry sichern
reg.exe export "%MOSER_KEY_SYSTEM%" "%BACKUP_REG_SYSTEM%" /y 1>nul
@ECHO Sicherung der MOS'aik-System Registry: %BACKUP_REG_SYSTEM%
:: Moser User Registry sichern
reg.exe export "%MOSER_KEY_USER%" "%BACKUP_REG_USER%" /y 1>nul
@ECHO Sicherung der MOS'aik-Registry des aktuellen Benutzers: %BACKUP_REG_USER%
:: MOS'aik FILTER
@ECHO. >>%TMPFILE1%
@ECHO FILTER: >>%TMPFILE1%
@ECHO ------- >>%TMPFILE1%
reg.exe query "%MOSER_KEY_PADS%" /F "Filters" /S /K /E >>%TMPFILE2%
FOR /F "tokens=*" %%i IN (%TMPFILE2%) DO (
@echo %%i >>%TMPFILE1%
IF NOT "%%i"=="" reg.exe query "%%i" /S >>%TMPFILE1% 2>nul
)
:: MOS'aik SPALTENLAYOUTS
@ECHO. >>%TMPFILE1%
@ECHO SPALTENLAYOUTS: >>%TMPFILE1%
@ECHO --------------- >>%TMPFILE1%
reg.exe query "%MOSER_KEY_PADS%" /F "Columns" /S /E >>%TMPFILE1%
:: Zeilenumbrüche einfügen
chcp 850 > nul
powershell -Command "(Get-Content %TMPFILE1% -encoding UTF8).replace(\"\0\", \"`r`n\") | Out-File -encoding UTF8 %BACKUP_REG_USER_TXT%"
REM TYPE %TMPFILE1% > %BACKUP_REG_USER%"
DEL /F "%TMPFILE1%" "%TMPFILE2%"
:: Fertig
@ECHO Sicherung von MOS'aik-Benutzereinstellungen: %BACKUP_REG_USER_TXT%
PAUSE-
Kopieren Sie das Skript dazu in eine Textdatei und speichern Sie diese z.B. unter dem Namen
registryBackupMoser.batab. -
Passen Sie das Verzeichnis des Dateiablageordners in der Zeile
SET ARCHIV=an, um die Datensicherung im gewünschten Dateiablageverzeichnis zu speichern. Das Verzeichnis wird bei der Ausführung des Skriptes ggf. automatisch angelegt.C:\MOSaik\Archivordner -
Rufen Sie das Skript regelmäßig auf, um Ihre Einstellungen zu sichern oder richten Sie eine entsprechende Aufgabe in der Microsoft Windows® Aufgabenplanung ein. In einer Mehrbenutzerumgebung muss das Skript für jeden Benutzer separat ausgeführt werden.
Das Skript darf allerdings auf demselben System nicht mehrfach zur selben Zeit ausgeführt werden!
Daten wiederherstellen
Die Wiederherstellung der Daten erfolgt lediglich manuell. Die gesicherten Informationen (s.o.) dienen in diesem Fall als Referenz, es ist aber insbesondere nach einem Update nicht zulässig, die Daten ohne gesonderte Prüfung wiederherzustellen. Sollte eine Wiederherstellung der Benutzereinstellungen relevant sein, wenden Sie sich dazu an den Moser Produktservice (Kontakt).
Siehe auch: Abschnitt 5.1.6, „Sicherungskonzept“
[84] Ersetzen Sie die Felder <Benutzername>, <Tabellenname> und <Datum> mit ihrem Benutzernamen, dem Tabellennamen (z.B. Adressen) und dem aktuellen Datum (z.B. 01.01.2021).